(ns auto-ap.graphql.vendors
  (:require
   [auto-ap.datomic :refer [audit-transact conn pull-attr remove-nils]]
   [auto-ap.datomic.vendors :as d-vendors]
   [auto-ap.graphql.utils
    :refer [->graphql
            <-graphql
            assert-admin
            assert-failure
            cleanse-query
            enum->keyword
            is-admin?
            result->page]]
   [auto-ap.search :as search]
   [auto-ap.utils :refer [heartbeat]]
   [clojure.set :as set]
   [clojure.string :as str]
   [clojure.tools.logging :as log]
   [datomic.client.api :as dc]
   [yang.scheduler :as scheduler]
   [mount.core :as mount]))

(defn can-user-edit-vendor? [vendor-id id]
  (if (is-admin? id)
        true
        (empty? 
          (set/difference (set (->> (dc/q '[:find ?c
                                            :in $ ?v
                                            :where [?vu :vendor-usage/vendor ?v]
                                            [?vu :vendor-usage/client ?c]
                                            [?vu :vendor-usage/count ?d]
                                            [(>= ?d 0)]]
                                          (dc/db conn)
                                          vendor-id)
                                    (map first)))
                          (set (map :db/id (:user/clients id)))))))

(defn upsert-vendor [context {{:keys [id name hidden terms code print_as primary_contact secondary_contact address default_account_id invoice_reminder_schedule schedule_payment_dom terms_overrides account_overrides] :as in} :vendor} _]
  (when (and id (not (can-user-edit-vendor? id (:id context))))
    (assert-failure "This vendor is managed by Integreat. Please reach out to ben@integreatconsult.com for your changes."))

  (when (->> schedule_payment_dom
             (group-by :client_id)
             vals
             (filter #(> (count %) 1))
             seq)
    (assert-failure "Only one schedule payment override allowed per client."))

  (when (->> terms_overrides
             (group-by :client_id)
             vals
             (filter #(> (count %) 1))
             seq)
    (assert-failure "Only one terms override allowed per client."))

  (when (->> account_overrides
             (group-by :client_id)
             vals
             (filter #(> (count %) 1))
             seq)
    (assert-failure "Only one account override allowed per client."))

  (let [
        hidden (if (is-admin? (:id context))
                 hidden
                 false)
        existing  (pull-attr (dc/db conn) :vendor/name id)
        terms-overrides (mapv
                        (fn [to]
                          (cond-> 
                              #:vendor-terms-override {:client (:client_id to)
                                                       :terms (:terms to)}
                              (:id to) (assoc :db/id (:id to))))
                        terms_overrides)
        account-overrides (mapv
                           (fn [ao]
                             (cond-> 
                                 #:vendor-account-override {:client (:client_id ao)
                                                            :account (:account_id ao)}
                                 (:id ao) (assoc :db/id (:id ao))))
                           account_overrides)
        schedule-payment-dom (mapv
                           (fn [ao]
                             (cond-> 
                                 #:vendor-schedule-payment-dom {:client (:client_id ao)
                                                                :dom (:dom ao)}
                               (:id ao) (assoc :db/id (:id ao))))
                           schedule_payment_dom)
        transaction (cond-> 
                        [(remove-nils (cond-> #:vendor {:db/id (if id
                                                                 id
                                                                 "vendor")
                                                        :name name
                                                        :code code
                                                        :hidden hidden
                                                        :terms terms
                                                        :print-as print_as
                                                        :default-account default_account_id
                                                        :invoice-reminder-schedule (keyword invoice_reminder_schedule)
                                                        :address (when address
                                                                   (remove-nils #:address {:db/id (if (:id address)
                                                                                                    (:id address)
                                                                                                    "address")
                                                                                           :street1 (:street1 address)
                                                                                           :street2 (:street2 address)
                                                                                           :city (:city address)
                                                                                           :state (:state address)
                                                                                           :zip (:zip address)}))
                                                        :primary-contact (when primary_contact

                                                                           (remove-nils #:contact {:db/id (if (:id primary_contact)
                                                                                                            (:id primary_contact)
                                                                                                            "primary")
                                                                                                   :name (:name primary_contact)
                                                                                                   :phone (:phone primary_contact)
                                                                                                   :email (:email primary_contact)}))
                                                        :secondary-contact (when secondary_contact

                                                                             (remove-nils #:contact {:db/id (if (:id secondary_contact)
                                                                                                              (:id secondary_contact)
                                                                                                              "secondary")
                                                                                                     :name (:name secondary_contact)
                                                                                                     :phone (:phone secondary_contact)
                                                                                                     :email (:email secondary_contact)})
                                                                             )}
                                        (is-admin? (:id context)) (assoc
                                                                    :vendor/legal-entity-name (:legal_entity_name in)
                                                                   :vendor/legal-entity-first-name (:legal_entity_first_name in)
                                                                   :vendor/legal-entity-middle-name (:legal_entity_middle_name in)
                                                                   :vendor/legal-entity-last-name (:legal_entity_last_name in)
                                                                   :vendor/legal-entity-tin (:legal_entity_tin in)
                                                                   :vendor/legal-entity-tin-type (enum->keyword (:legal_entity_tin_type in) "legal-entity-tin-type") 
                                                                   :vendor/legal-entity-1099-type (enum->keyword (:legal_entity_1099_type in) "legal-entity-1099-type"))))]
                        (is-admin? (:id context)) (conj [:reset (if id id "vendor") :vendor/account-overrides account-overrides])
                        (is-admin? (:id context)) (conj [:reset (if id id "vendor") :vendor/terms-overrides terms-overrides])
                        (is-admin? (:id context)) (conj [:reset (if id id "vendor") :vendor/schedule-payment-dom schedule-payment-dom])
                        (is-admin? (:id context)) (conj [:reset (if id id "vendor") :vendor/automatically-paid-when-due
                                                         (mapv
                                                          (fn [apwd]
                                                            {:db/id apwd})
                                                          (:automatically_paid_when_due in))])
                        (not= (:vendor/name existing) name) (conj [:reset (if id id "vendor") :vendor/search-terms [name]]))

        _ (log/info "Upserting vendor" transaction)
        transaction-result (audit-transact transaction (:id context))]
    
    (-> (d-vendors/get-by-id (or (-> transaction-result :tempids (get "vendor"))
                                 id))
        (->graphql))))

(defn merge-vendors [context {:keys [from to]} _]
  (let [transaction (->> (dc/q {:query {:find '[?x ?a2]
                                           :in '[$ ?vendor-from ]
                                           :where ['[?x ?a ?vendor-from]
                                                   '[?a :db/ident ?a2]]}
                                   :args [(dc/db conn) from]})
                         (mapcat (fn [[src attr]]

                                   [[:db/retract src attr from]
                                    [:db/add src attr to]])))
        transaction (conj transaction [:db/retractEntity from])]
    (audit-transact transaction (:id context))
    to))


(defn get-graphql [context args _]
  (assert-admin (:id context))
  (let [args                     (assoc args :id (:id context))
        [vendors vendors-count ] (d-vendors/get-graphql  (<-graphql args))]
    (result->page vendors vendors-count :vendors args)))

(defn get-by-id [context args _]
  (->graphql
    (d-vendors/get-graphql-by-id (assoc args :id (:id context))
                                 (:id args))))

(defn partial-match-first [query matches]
  (if-let [best-match (->> matches
                           (filter (fn [[n]]
                                     (str/starts-with? (str/lower-case n)
                                                       (str/lower-case query))))
                           first)]
    (cons best-match
          (filter (complement #{best-match})
                  matches))
    matches))

(defn search [context args _]
  (let [search-query (cleanse-query (:query args))]
    (for [[id name] (search/search (cond-> {:q search-query}
                                     (not (is-admin? (:id context))) (assoc :hidden false))
                                   "vendor")]
      {:name name
       :id   id})
    ))

(defn rebuild-search-index []
  (search/full-index-query  
    (for [result (map first (dc/qseq '[:find (pull ?v [:vendor/search-terms :db/id :vendor/name :vendor/hidden])
                                       :in $
                                       :where [?v :vendor/search-terms ]]
                                     (dc/db conn)))]
      {:id     (:db/id result)
       :text   (or (first (:vendor/search-terms result))
                   (:vendor/name result))
       :hidden (boolean (:vendor/hidden result))})
    "vendor"))

#_{:clj-kondo/ignore [:clojure-lsp/unused-public-var]}
(mount/defstate indexer
  :start (scheduler/every (* 5 60 1000) (heartbeat rebuild-search-index "rebuild-search-index"))
  :stop (scheduler/stop indexer))
